Due tipi di cadute a caso di proiettili in un bersaglio.  Vogliamo stimare sperimentalmente la probabilità che, prendendo "a caso" un punto in un bersaglio composto da due cerchi concentrici con raggi uno doppio dell'altro, il punto cada nel cerchio centrale.  Consideriamo due possibili procedimenti mediante i quali viene generato un punto che cade nel cerchio di centro O=(0,0) e raggio 1 e verificato  se la sua distanza da O è minore di 1/2,  ovvero  se il quadrato di essa è minore di 0.25.
I seguenti programmi in Basic stampano la percentuale dei punti che cadono nel cerchio piccolo.
Le variabili lanci e ok contano una i lanci, l'altra quelli che centrano il cerchio piccolo.

10 input "n = "; n : lanci=0 : ok=0
20 while lanci < n
30   x = rnd*2-1 : y = rnd*2-1
40   if x*x+y*y < 1 then gosub 100
50 wend
60 print "% caduti in cerchio piccolo "; ok/lanci*100;"%" : goto 10
100 lanci = lanci + 1 : if x*x+y*y < 0.25 then ok = ok+1
110 return
n =  1e2
% caduti in cerchio piccolo 29.0%
n =  1e3
% caduti in cerchio piccolo 24.8%
n =  1e4
% caduti in cerchio piccolo 25.04%
n =  1e5
% caduti in cerchio piccolo 24.814%
n =  1e6
% caduti in cerchio piccolo 25.0058%

Capisco che → 25%

 

10 input "n = "; n : lanci=0 : ok=0
20 while lanci < n
30   r = rnd : a = rnd*6.2831853071795865 : x=r*cos(a) : y = r*sin(a)
40   if x*x+y*y < 1 then gosub 100
50 wend
60 print "% caduti in cerchio piccolo "; ok/lanci*100;"%" : goto 10
100 lanci = lanci + 1 : if x*x+y*y < 0.25 then ok = ok+1
110 return
n =  1e2
% caduti in cerchio piccolo 46%
n =  1e3
% caduti in cerchio piccolo 51.5%
n =  1e4
% caduti in cerchio piccolo 50.57%
n =  1e5
% caduti in cerchio piccolo 49.986%
n =  1e6
% caduti in cerchio piccolo 49.9307%

Capisco che → 50%